StockFetcher Forums · Public Filter List · GUPPY revisited<< 1 2 >>Post Follow-up
graftonian
815 posts
msg #135310
Ignore graftonian
modified
4/6/2017 4:16:03 PM

Cannot figure out how to make this "clickable"

fetcher[
/*Guppy MMA */
market is not OTCBB
market market is not ETF
Average Volume(30) > 250000
close between .50 and 100

/*TRADER GROUP*/
draw EMA(3)
draw EMA(5)
draw EMA(7)
draw EMA(9)
draw EMA(11)
draw EMA(13)

/*INVESTOR GROUP*/
draw EMA(70)
draw EMA(60)
draw EMA(50)
draw EMA(40)
draw EMA(35)
draw EMA(30)
add column separator

/* investor group width */
set{igw, ema(30) - ema(70)}
set{igw2, igw / ema(70)}
set{IGwidth, igw2 * 100}
add column IGwidth

/*trader grp/investor grp separation */
/*The "white space" between the trader and investor groups*/
set{tradgrpmin, min(ema(3), ema(13))}
set{invgrpmax, max(ema(30), ema(70))}
set{tisep, tradgrpmin - invgrpmax}
set{tisep2, tisep / invgrpmax}
set{TG_IGsep, tisep2 * 100}
add column TG_IGsep
TG_IGsep > 0 /*to be sure there is some "White space" between groups*/

/* trader group width */
set{tgw, ema(3) - ema(13)}
set{tgw2, tgw / ema(13)}
set{TGwidth, tgw2 * 100}
add column TGwidth
draw TGwidth
draw TGwidth line at 0
draw TGwidth line at -10
TGwidth greater than TGwidth 1 day ago/*trader group is still in expansion mode*/

add column separator

/*days since investor group reverted or crossed above 0 */
/*not used in this version*/
set{IGX, days(IGwidth < 0, 100)}
add column IGX

/*days since trader group reverted*/
set{TGX, days(TGwidth < 0, 100)}
add column TGX

TGX between 0 and 3 /*trader group "flipped" recently*/
/*This parameter is open to discussion*/

/*A couple of bells and whistles for back testing*/
set{entry, close}
set{target, entry * 1.10}
set{ stop, entry * 0.95}
draw price line at entry
draw price line at target
draw price line at stop

/*To determine if expansion is accelerating*/
add column 5 day slope of TGwidth
5 day slope of TGwidth greater than 5 day slope of TGwidth 1 day ago
5 day slope TGwidth greater than 2
sort on column 12 descending

volume > Average Volume(30)/*a volume consideration*/
close > open /*an up day*/

set{TGwidthPerDay, TGwidth / TGX} /*trader group expansion per day since flip*/
add column TGwidthPerDay
/*Much to say about this measure. Too much, too soon seem to fizzle and too little seems to lack conviction*/
/*The optimum seems to be around 2.5 to 4.5, but I could use soom help on testing this*/

chart-time is 100 days
do not draw TGX
do not draw TG_IGsep

/*Take a look at the results for 5jan17. What would you choose? */
/*CBAY- a gap up, never mind. only 4 more to eliminate*/
/*WFT, HBM- TGWPD (tradergrpwidthperday) too low*/
/*SBLK- investor group not completely flipped, but close*/
/*that leaves BCEI and UUUU. I chose UUUU, only because it was a little more dedveloped, and the
investor group just flipped*/
]

nibor100
398 posts
msg #135328
Ignore nibor100
4/7/2017 2:20:35 PM

@graftonian

Cannot figure out how to make this "clickable"

It was the question mark in one of your comment lines

Ed S.

Fetcher[
/*Guppy MMA */
market is not OTCBB
market market is not ETF
Average Volume(30) > 250000
close between .50 and 100

/*TRADER GROUP*/
draw EMA(3)
draw EMA(5)
draw EMA(7)
draw EMA(9)
draw EMA(11)
draw EMA(13)

/*INVESTOR GROUP*/
draw EMA(70)
draw EMA(60)
draw EMA(50)
draw EMA(40)
draw EMA(35)
draw EMA(30)
add column separator

/* investor group width */
set{igw, ema(30) - ema(70)}
set{igw2, igw / ema(70)}
set{IGwidth, igw2 * 100}
add column IGwidth

/*trader grp/investor grp separation */
/*The "white space" between the trader and investor groups*/
set{tradgrpmin, min(ema(3), ema(13))}
set{invgrpmax, max(ema(30), ema(70))}
set{tisep, tradgrpmin - invgrpmax}
set{tisep2, tisep / invgrpmax}
set{TG_IGsep, tisep2 * 100}
add column TG_IGsep
TG_IGsep > 0 /*to be sure there is some "White space" between groups*/

/* trader group width */
set{tgw, ema(3) - ema(13)}
set{tgw2, tgw / ema(13)}
set{TGwidth, tgw2 * 100}
add column TGwidth
draw TGwidth
draw TGwidth line at 0
draw TGwidth line at -10
TGwidth greater than TGwidth 1 day ago/*trader group is still in expansion mode*/

add column separator

/*days since investor group reverted or crossed above 0 */
/*not used in this version*/
set{IGX, days(IGwidth < 0, 100)}
add column IGX

/*days since trader group reverted*/
set{TGX, days(TGwidth < 0, 100)}
add column TGX

TGX between 0 and 3 /*trader group "flipped" recently*/
/*This parameter is open to discussion*/

/*A couple of bells and whistles for back testing*/
set{entry, close}
set{target, entry * 1.10}
set{ stop, entry * 0.95}
draw price line at entry
draw price line at target
draw price line at stop

/*To determine if expansion is accelerating*/
add column 5 day slope of TGwidth
5 day slope of TGwidth greater than 5 day slope of TGwidth 1 day ago
5 day slope TGwidth greater than 2
sort on column 12 descending

volume > Average Volume(30)/*a volume consideration*/
close > open /*an up day*/

set{TGwidthPerDay, TGwidth / TGX} /*trader group expansion per day since flip*/
add column TGwidthPerDay
/*Much to say about this measure. Too much, too soon seem to fizzle and too little seems to lack conviction*/
/*The optimum seems to be around 2.5 to 4.5, but I could use soom help on testing this*/

chart-time is 100 days
do not draw TGX
do not draw TG_IGsep

/*Take a look at the results for 5jan17. What would you choose */
/*CBAY- a gap up, never mind. only 4 more to eliminate*/
/*WFT, HBM- TGWPD (tradergrpwidthperday) too low*/
/*SBLK- investor group not completely flipped, but close*/
/*that leaves BCEI and UUUU. I chose UUUU, only because it was a little more dedveloped, and the
investor group just flipped*/





]




graftonian
815 posts
msg #135339
Ignore graftonian
4/8/2017 10:11:43 AM

nibor100, A big "thank you ".

pthomas215
1,251 posts
msg #135346
Ignore pthomas215
4/9/2017 12:17:14 PM

GRAF, you are certainly the guru of filters. so i noticed that when tgwidth crosses above 0, that is when you see the largest escalation. I went back and found a few that might cross monday or tuesday (BID, MDCO) but is there a way to write this into the SF filter? I tried but got no results. I hope I explained that ok.

graftonian
815 posts
msg #135347
Ignore graftonian
4/9/2017 2:42:57 PM

I modified the original filter to include the EMAs used by Daryl Guppy and added the days since investor group "flip". I totaled IGX and TGX to come with squeeze, with zero being nirvana.
On a side note, if one lets "squeeze" run out to 12 or so days, this starts to look like a short filter.

Fetcher[
/*Guppy MMA */
market is not OTCBB
Average Volume(30) > 100000
close greater than 0.50

/*TRADER GROUP*/
draw EMA(3)
draw EMA(5)
draw EMA(8)
draw EMA(10)
draw EMA(12)
draw EMA(15)

/*INVESTOR GROUP*/
draw EMA(60)
draw EMA(50)
draw EMA(45)
draw EMA(40)
draw EMA(35)
draw EMA(30)
add column separator

/* investor group width */
set{igw, ema(30) - ema(60)}
set{igw2, igw / ema(60)}
set{IGwidth, igw2 * 100}
add column IGwidth

/*trader grp/investor grp separation */
/*The "white space" between the trader and investor groups*/
set{tradgrpmin, min(ema(3), ema(15))}
set{invgrpmax, max(ema(30), ema(60))}
set{tisep, tradgrpmin - invgrpmax}
set{tisep2, tisep / invgrpmax}
set{TG_IGsep, tisep2 * 100}
add column TG_IGsep
TG_IGsep > 0 /*to be sure there is some "White space" between groups*/

/* trader group width */
set{tgw, ema(3) - ema(15)}
set{tgw2, tgw / ema(15)}
set{TGwidth, tgw2 * 100}
add column TGwidth
draw TGwidth
draw TGwidth line at 0
draw TGwidth line at -10
TGwidth greater than TGwidth 1 day ago/*trader group is still in expansion mode*/

add column separator

/*days since investor group reverted or crossed above 0 */
set{IGX, days(IGwidth < 0, 200)}
add column IGX
IGX greater than -1

/*days since trader group reverted*/
set{TGX, days(TGwidth < 0, 200)}
add column TGX

/*find stocks with maximmum compression*/
set{squeeze, IGX + TGX}
add column squeeze
sort on column 12 ascending
/*A couple of bells and whistles for back testing*/
set{entry, close}
set{target, entry * 1.10}
set{ stop, entry * 0.95}
draw price line at entry
draw price line at target
draw price line at stop

/*To determine if expansion is accelerating*/
add column 5 day slope of TGwidth
5 day slope of TGwidth greater than 5 day slope of TGwidth 1 day ago
5 day slope TGwidth greater than 2

volume > Average Volume(30)/*a volume consideration*/
close > open /*an up day*/

set{TGwidthPerDay, TGwidth / TGX} /*trader group expansion per day since flip*/
add column TGwidthPerDay
/*Much to say about this measure. Too much, too soon seem to fizzle and too little seems to lack conviction*/
/*The optimum seems to be around 2.5 to 4.5, but I could use some help on testing this*/

chart-time is 100 days
do not draw TGX
do not draw IGX
do not draw TG_IGsep
]



graftonian
815 posts
msg #135348
Ignore graftonian
modified
4/9/2017 2:59:13 PM

PT, GRAF, you are certainly the guru of filters. so i noticed that when tgwidth crosses above 0, that is when you see the largest escalation. I went back and found a few that might cross monday or tuesday (BID, MDCO) but is there a way to write this into the SF filter? I tried but got no results. I hope I explained that ok.


Thanks for the compliment, but the real pros are guys like Kevin, TRO, et al , that have been at this a lot longer. But to your question, try the filter in th nest post

graftonian
815 posts
msg #135350
Ignore graftonian
4/9/2017 3:27:30 PM

Fetcher[
/*Guppy MMA */
/*Experiment to find those about to break out*/
market is not OTCBB
Average Volume(30) > 100000
close between .50 and 200

/*TRADER GROUP*/
draw EMA(3)
draw EMA(5)
draw EMA(8)
draw EMA(10)
draw EMA(12)
draw EMA(15)

/*INVESTOR GROUP*/
draw EMA(60)
draw EMA(50)
draw EMA(45)
draw EMA(40)
draw EMA(35)
draw EMA(30)
add column separator

/* investor group width */
set{igw, ema(30) - ema(60)}
set{igw2, igw / ema(60)}
set{IGwidth, igw2 * 100}
add column IGwidth

/*trader grp/investor grp separation */
/*The "white space" between the trader and investor groups*/
set{tradgrpmin, min(ema(3), ema(15))}
set{invgrpmax, max(ema(30), ema(60))}
set{tisep, tradgrpmin - invgrpmax}
set{tisep2, tisep / invgrpmax}
set{TG_IGsep, tisep2 * 100}
add column TG_IGsep
/*to be sure there is some "White space" between groups*/
TG_IGsep > 0

/* trader group width */
set{tgw, ema(3) - ema(15)}
set{tgw2, tgw / ema(15)}
set{TGwidth, tgw2 * 100}
add column TGwidth
draw TGwidth
draw TGwidth line at 0
draw TGwidth line at -10
/*trader group is still in expansion mode*/
TGwidth greater than TGwidth 1 day ago
/*trader group is inverted*/
TGwidth < 0
add column separator

set{IGX, days(IGwidth < 0, 100)}
add column IGX

set{TGX, days(TGwidth < 0, 100)}
add column TGX

/*A couple of bells and whistles for back testing*/
set{entry, close}
set{target, entry * 1.10}
set{ stop, entry * 0.95}
draw price line at entry
draw price line at target
draw price line at stop

/*To determine if expansion is accelerating*/
add column 5 day slope of TGwidth
5 day slope of TGwidth greater than 5 day slope of TGwidth 1 day ago
5 day slope of TGwidth greater than 0

volume > Average Volume(30)/*a volume consideration*/
close > open /*an up day*/

set{TGwidthPerDay, TGwidth / TGX} /*trader group expansion per day since flip*/
add column TGwidthPerDay


chart-time is 100 days
do not draw TGX
do not draw TG_IGsep
]



pthomas215
1,251 posts
msg #135351
Ignore pthomas215
4/9/2017 3:51:19 PM

Once again, thank you. and yes, Kevin n Tro...they are pretty savvy with this stuff. Four too.

nibor100
398 posts
msg #135432
Ignore nibor100
4/14/2017 4:27:01 AM

@Graftonian,

Looking at the first filter results for Jan 5:

My first pick would be SBLK as the numbers seem to show that both groups are aligned properly whereas they are not quite for UUUU.

2nd pick CBAY due to closing higher on the 5th

3rd pick HBM investor group spread stayed fairly constant during recent large decline and trader group turning upward

4th UUUU

Ed S.

graftonian
815 posts
msg #135434
Ignore graftonian
4/14/2017 2:19:11 PM

Ed S.
I cannot agree with your ranking of the picks for Jan 5. Perhaps it is my aversion to Gap-ups. The gap on CBAY was probably news driven, considering it is a pharma stock. CBAY stopped out by noon of the 6th, but then so did UUUU. BCEI, on the other hand went on to a nice profit.
I've changed direction concerning entry times. My current thinking is an 0845 buy if the price is above an ascending ema13 on the 15 minute chart; all other factors being "reasonable".
I do not see anything promising for Monday morning, but if had to choose, it would be COUP. On Thursday I Got into (and out of) ZIOP with not much to show for my trouble; only another 3 day settlement period and beer money.
Keep the critiques and the observations coming.
Happy Easter,
Duane



















StockFetcher Forums · Public Filter List · GUPPY revisited<< 1 2 >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2018 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus