StockFetcher Forums · Filter Exchange · BOTTOM FISHIN' FOR GUPPYS<< >>Post Follow-up
graftonian
810 posts
msg #135570
Ignore graftonian
4/22/2017 9:15:31 PM

Fetcher[
/*BOTTOM FISHIN' FOR GUPPYS*/
/*APR 22 2017*-*/
/*TRADER GROUP*/
draw EMA(3) and draw EMA(5) and draw EMA(8) draw EMA(10) and draw EMA(12) and draw EMA(15)
/*INVESTOR GROUP*/
draw EMA(60) and draw EMA(50) and draw EMA(45) and draw EMA(40) and draw EMA(35) and draw EMA(30)
add column separator
/* investor group width */
set{igw, ema(30) - ema(60)}
set{igw2, igw / ema(60)}
set{IGwidth, igw2 * 100}
add column IGwidth
/*trader grp/investor grp separation */
/*The "white space" between the trader and investor groups*/
set{tradgrpmin, min(ema(3), ema(15))}
set{invgrpmax, max(ema(30), ema(60))}
set{tisep, tradgrpmin - invgrpmax}
set{tisep2, tisep / invgrpmax}
set{TG_IGsep, tisep2 * 100}
add column TG_IGsep
/* trader group width */
set{tgw, ema(3) - ema(15)}
set{tgw2, tgw / ema(15)}
set{TGwidth, tgw2 * 100}
add column TGwidth
add column separator
add column 2 day slope of igwidth
add column 2 day slope of tg_igsep
add column 2 day slope of tgwidth
/*volume as a % of average vollume(30)*/
set{vol1, volume / Average Volume(30)}
set{vol2, vol1 - 1}
set{vol_pct, vol2 * 100}
add column vol_pct
draw igwidth
draw tg_igsep
draw tgwidth
/*A couple of bells and whistles for back testing*/
set{entry, close}
set{target, entry * 1.10}
set{ stop, entry * 0.95}
draw price line at entry
draw price line at target
draw price line at stop
market market is not OTCBB
close between 0.50 and 100
Average Volume(30) > 100000
sort on column 6 ascending
chart-time is 100 days
/****************FILTER****************/
/*investor group has hit new low, and held for 2 days*/
IGwidth reached 100 day low 2 days ago
igwidth 1 day ago > igwidth 2 days ago
igwidth > igwidth 1 day ago
/*white space is improving faster than investor group*/
2 day slope of tg_igsep > 2 day slope of igwidth
/*trader group faster still*/
2 day slope of tgwidth > 2 day slope of tg_igsep
vol_pct > 10
]



graftonian
810 posts
msg #135571
Ignore graftonian
4/22/2017 9:53:17 PM

If interested, add this, just above the filter section:

draw vol_pct line at 0
draw igwidth line at 0
draw tg_igsep line at 0
draw tgwidth line at 0

StockFetcher Forums · Filter Exchange · BOTTOM FISHIN' FOR GUPPYS<< >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2018 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus