StockFetcher Forums · View by Author: xarlor (114 messages) ·  [ Display By: Date / Subject ]<< 1 ... 8 9 10 11 12 >> 
Stock Picks and Trading · Weinstein Strategy Picks
xarlor
msg #148431
7/8/2019 11:41:04 PM

@graft, I would say it's still Stage 1. The lack of volume when it broke the weekly MA(30) last time prevented it from taking off in a Stage 2. Pay close attention to a possible bounce off the weekly MA(30) coming up, though. If it bounces off and volume shoots up could be the Stage 2 we're waiting for.

Basic Materials sector is also bullish, so just waiting for the volume right now. We're wanting something like July of 2018 and late January of 2019.



Fetcher[
symlist(clf,xlb)
draw wma(150)
chart-time is 3 years
add column sector
]



Stock Picks and Trading · Weinstein Strategy Picks
xarlor
msg #148420
7/7/2019 7:53:58 PM

@ron22 Ah, good catch! I modified it to just take into account recent volume increases:

Fetcher[
chart-time is 3 years
optionable
market not etf

average volume(30) > 1234657
close > 5
close crossed above wma(150)
close 1 day ago < wma(150) for last 30 days
volume increasing for last 2 days
add column sector
Relative Strength(^SPX,150) > 1.0
30-day slope of Relative Strength(^SPX,150) > 0
]



Stock Picks and Trading · Weinstein Strategy Picks
xarlor
msg #148415
modified
7/7/2019 12:52:49 PM

WYNN popped up on my Stage 2 Weinstein filter on 07/01/19.
Ticks all the boxes:

Broke resistance
Broke above WMA(150)
Positive relative strength and sloping up
Sector is bullish




Other tickers to consider with the same set up:
LVS
SWKS

Fetcher[
chart-time is 3 years
optionable
market not etf

average volume(30) > 1234657
close > 5
close crossed above wma(150)
close 1 day ago < wma(150) for last 30 days
average volue(30) > average volume(30) 5 days ago
add column sector
Relative Strength(^SPX,150) > 1.0
30-day slope of Relative Strength(^SPX,150) > 0
]



General Discussion · Stan Weinstein's Secrets For Profiting in Bull and Bear Markets
xarlor
msg #148373
modified
7/4/2019 12:33:22 PM

"talked about how this ratio can be negative or positive. This can't be negative the way he defined it. What am I missing?"

I presume he means anything above 1.0 is positive (outperforming the comparing index) and below 1.0 is negative (underperforming the comparing index).

Fetcher[
symlist(SPY,AMZN,DAL)
add column Relative Strength(^SPX,150)
]



Filter Exchange · EMA Crossover
xarlor
msg #148347
7/2/2019 11:27:08 PM

No backtester here on SF. Best you can do is hit the back arrow on each filter to see the past performance. Others may offer some backtesting sites or software.

Filter Exchange · EMA Crossover
xarlor
msg #148337
modified
7/2/2019 1:45:00 PM

Fetcher[
/* EMA(4) Cross above EMA(9) and EMA(12) form 1 point, then EMA(4) cross above EMA21 in the same day, EMA(4) crossover EMA(30) in the next day. */

close > 5
average volume(30) > 100000

ema(4) 1 day ago crossed above ema(9) 1 day ago
ema(4) 1 day ago crossed above ema(12) 1 day ago
ema(4) 1 day ago crossed above ema(21) 1 day ago
ema(4) crossed above ema(30)
]



Fetcher[
/* 2 days ago, EMA(4) EMA(9) EMA(12) EMA(21) EMA(30) are cross above each other within the same candlestick body. For example, 2 days ago, EMA(4) crossover EMA(12), EMA(9) and EMA(21) are either above or below EMA(4) but they appear within the same candlestick body. */

close > 5
average volume(30) > 100000

ema(4) 2 days ago crossed above ema(12) 2 days ago
ema(4) 2 days ago between open 2 days ago and close 2 days ago
ema(9) 2 days ago between open 2 days ago and close 2 days ago
ema(12) 2 days ago between open 2 days ago and close 2 days ago
ema(21) 2 days ago between open 2 days ago and close 2 days ago
ema(30) 2 days ago between open 2 days ago and close 2 days ago

draw ema(4)
draw ema(9)
draw ema(12)
draw ema(21)
draw ema(30)
]



Fetcher[
/* moving narrow range of Bollinger band for 2 months, then the day that Bollinger band expands 5% either up or down. */

market not etf
close > 5
average volume(30) > 500000

Bollinger Width(20) 1 day ago < 0.05 for past 40 days

set{var1,Upper Bollinger Band(20) - Lower Bollinger Band(20)}
set{var2,var1 1 day ago}
set{var3,var1/var2}
set{var4,count(var3 >= 1.05,1)}
set{var5,count(var3 <= 0.95,1)}
set{var6,var4 + var5}
var6 > 0

sort column 7 descending

add column var1
add column var2
add column var3
add column var4
add column var5
add column var6

draw Lower Bollinger Band(20)
draw Upper Bollinger Band(20)
]



Filter Exchange · doji sandwich
xarlor
msg #148329
7/1/2019 11:42:08 PM

My first pass at a doji sandwich.

Fetcher[
/* Doji Sandwich */
/* Doji (H/L Rng above .20 w/Candle Body less than 30% of H/L Rng) by alf44*/

close > 5
average volume(30) > 1234567

set{HiLoRng, High - Low}
set{ClOpRng, abs(Close minus Open)}
set{ClOp_HiLo_ratio, ClOpRng / HiLoRng}
set{Range, count(HiLoRng is above .20, 1)}
set{Body, count(ClOp_HiLo_ratio is less than .30, 1)}
set{doji, Range * Body}

close > open
close 2 days ago > open 2 days ago

doji 0 days ago < 1
doji 1 day ago > 0
doji 2 days ago < 1

close 1 day ago < high 2 days ago
close 1 day ago > open 2 days ago
close > close 1 day ago

add column doji
]



General Discussion · Stan Weinstein's Secrets For Profiting in Bull and Bear Markets
xarlor
msg #148311
modified
6/29/2019 10:13:54 PM

I started the book this weekend. I just read chapter 1 and decided to make a filter based on his five points on pages 25-27. Color me impressed.

Fetcher[
market is not etf
optionable
average volume(30) > 500000
low > 5

/* 1-2: General assumptions about price and volume */
close > open
close 1 day ago > open 1 day ago
volume > volume 1 day ago

/* 3: 30-week MA */
close > MA(150)

/* 4: Long-range background */
set{var1,high 1 day ago}
set{var2, high 3-year high 2 days ago}
set{NewHighs,count(var1 > var2,50)}
add column NewHighs
var1 > var2

/* 5: Relative-strength line */
Relative Strength(^SPX,150) > 1.5
30-day slope of Relative Strength(^SPX,150) > 0

draw ma(150)
draw high 3-year high
draw Relative Strength(^SPX,150)
do not draw var1
do not draw var2

]



General Discussion · ALL variables must be true
xarlor
msg #148227
6/22/2019 2:26:21 AM

Is this what you're looking for?

Fetcher[
market is not etf
market is not otcbb
day point range reached a new 7 day low
high 1 day ago < high 7 days ago
set{market_cap, shares outstanding * close}
market_cap > 200
add column market_cap
]



General Discussion · Need help for this filter. please
xarlor
msg #147917
5/24/2019 2:17:48 PM

@xarlor .... I see where you made the change on this part but. What im trying to formulate is .... the lowest low from either yesterdays close or todays low. And the highest high from either yesterdays close or todays high. Is that what your formula shows but in less steps than mine?

from xarlor .......
set{LL, min(low, close 1 day ago)}
set{HH, max(high, close 1 day ago)}

from me .....
set{LL1,low today}
set{LL2,close 1 day ago}
set{HH1,high today}
set{HH2,high 1 day ago}

-----------------------------------------------------

pa427, mine says:

Look at today's Low
Look at yesterday's Close
Give me whichever of the two prices is the lower one

Look at today's High
look at yesterday's Close
Give me whichever of the two prices is the higher one

Your original filter said:

Look at today's Low
Look at today's Close
Give me whichever of the two prices is the lower one

Look at today's High
look at today's Close
Give me whichever of the two prices is the higher one

As for what you posted here:

set{LL1,low today}
set{LL2,close 1 day ago}
set{HH1,high today}
set{HH2,high 1 day ago}

Yes, it's essentially the same thing, only you need to then get the low and high:
set{LL, min(LL1,LL2)}
set{HH, max(HH1,HH2)}

StockFetcher Forums ·  · << 1 ... 8 9 10 11 12 >>

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2018 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus