StockFetcher Forums · View by Author: xarlor (142 messages) ·  [ Display By: Date / Subject ]<< 1 ... 3 4 5 6 7 ... 15 >> 
Stock Picks and Trading · A Newbie's Journey
xarlor
msg #149694
11/27/2019 7:49:39 AM

just happened to see a big candle dwarf the 3 candles prior (is there a name or script for that?)


What you see there is a doji candlestick after a downtrend. Doji's are candles whose open and close are pretty much in the same spot. It reflects an even tug-of-war between the bulls and the bears and often signifies a reversal in the trend.

Specific doji more strongly predict a trend change:

  • Gravestone doji
  • Dragonfly doji
  • Morning star doji
  • Evening star doji

  • Stock Picks and Trading · CLVS
    xarlor
    msg #149692
    11/26/2019 8:50:34 PM

    Mac, is there a filter you use to catch these breakouts?

    I've pieced together one based on your criteria mentioned over the last several posts.

  • Guppy trend reversal
  • Break above 3-month high
  • Day range exceeds the average 30-day range

    This filter caught CLVS and RLGY, but missed MRNA (too much separation between guppy cross and 3-month break). It also found some other gems:

  • 10/18/19 STT
  • 10/25/19 URI
  • 10/28/19 FIT
  • 10/30/19 TAK
  • 11/13/19 HALO
  • 11/14/19 QGEN
  • 11/15/19 LK
  • 11/19/19 LABU

    Of course, as with any filter there are losers in there. I feel with a good stop loss plan this would make a good strategy for breakouts.

    Anyway, here is the filter:

    Fetcher[
    /* River Rat wants a new boat */

    chart-time is 4 months
    average volume(30) > 1234567
    close > 5

    set{3mh,high 3 month high}
    close crossed above 3mh 1 day ago
    close crossed above wma(150) within the last 7 days
    close > wma(150) for last 2 days
    close-to-open gap < 10
    day range > Average Day Range(30)

    draw price line at 3mh 1 day ago

    /*TRADER GROUP*/
    draw EMA(3)
    draw EMA(5)
    draw EMA(8)
    draw EMA(10)
    draw EMA(12)
    draw EMA(15)

    /*INVESTOR GROUP*/
    draw EMA(60)
    draw EMA(50)
    draw EMA(45)
    draw EMA(40)
    draw EMA(35)
    draw EMA(30)

    do not draw high 3 month high
    do not draw average day range(30)
    do not draw day range
    do not draw 3mh
    do not draw close-to-open gap
    ]



  • Filter Exchange · Swing trading filters
    xarlor
    msg #149679
    11/24/2019 9:00:43 PM

    Although KMX did have 5 down days, the bottom on 12/20/18 was not a doji.

    Let us know if you encounter success with the strategy though!



    General Discussion · Fibonacci screener
    xarlor
    msg #149676
    11/24/2019 5:44:54 PM

    @nibor, it appears to be some wonkiness with SF. Most of the extra tickers your filter displays have candle bodies of less than 0.01. Most of these are obviously penny and micro stocks, but not all of them. In this sense your filter is more accurate than mine.

    Still if you want to match my filter as closely as possible, you can eliminate these. It still does not mirror the filters perfectly but it's a lot closer. Plus, it gets rid of micro stocks too.

    Fetcher[

    average volume(30) > 1234567

    close 1 day ago < close 2 days ago
    close 2 days ago < close 3 days ago
    close 3 days ago < close 4 days ago

    set{Body1,open - close}
    set{Body,abs(Body1)}

    Body 2 days ago > 0.01
    Body 3 days ago > 0.01

    ]



    Filter Exchange · Swing trading filters
    xarlor
    msg #149673
    modified
    11/23/2019 11:28:51 PM

    Fetcher[
    /* After down trend of 5 days */
    close < close 1 day ago for last 5 days
    close 1 day ago < open 1 day ago for last 4 days

    /* Stock drops into the Stochastic oversold area */
    fast Stochastic(10) Fast %K is below 20

    /* it is a doji candlestick */
    set{body,close - open}
    body between -0.02 and 0.02

    /* The next days open is a gap up */
    /* Profit? */

    do not draw body
    ]



    General Discussion · The Rumpled One crock pot filter
    xarlor
    msg #149657
    11/21/2019 6:30:17 PM

    Okay I've started and scrapped this request several times before finally settling on this. It's a bit cumbersome, but I think it mostly gets what you need.

    To start, you have to move the day back to a Friday for it to work right, From there you can jump back 1 week at a time.

    The top line represents a 5% profit
    The middle line is a 1% profit
    The bottom line is a stop loss set 3% below your entry (the close price on Friday).

    At a glance, hitting the 1% profit before a 3% loss during the week is highly probable and occurs often enough to offset the occasional 3% loser.

    Trade idea: Set stop loss at 3%. At 1% profit, set a 1% trailing stop.

    Notes:
  • I had to remove the weekly display.
  • I removed ETFs from the results as there were just too many that move really slow and never cleared 1% during the week.
  • I added the suggestion in the original TRO thread about only entering during an uptrend. My loose definition of an uptrend is low > wma(150).
  • I added "Gaps" which shows you how many times in the last 52 weeks the weekly open was higher than the prior week's close.

    Fetcher[
    /* TRO STAT SCAN for SWING TRADERS */
    /* Enter Friday at the close added by Xarlor */

    set{whiop, weekly high - weekly open}
    set{Long_Profit, whiop / weekly open }
    set{wkProfitPct, 100 * Long_Profit }

    set{C1A, count(Long_Profit > .04 , 52)}
    set{C2A, count(Long_Profit > .09, 52)}
    set{C0010, C1A - C2A}

    set{D1A, count(Long_Profit > .09 , 52)}
    set{D2A, count(Long_Profit > .19, 52)}
    set{D1020, D1A - D2A}

    set{E1A, count(Long_Profit > .19 , 52)}
    set{E2A, count(Long_Profit > .29, 52)}
    set{E2030, E1A - E2A}

    set{F1A, count(Long_Profit > .29 , 52)}
    set{F2A, count(Long_Profit > .39, 52)}
    set{F3040, F1A - F2A}

    set{G1A, count(Long_Profit > .39 , 52)}
    set{G2A, count(Long_Profit > .49, 52)}
    set{G4050, G1A - G2A}

    set{H1A, count(Long_Profit > .49 , 52)}
    set{H2A, count(Long_Profit > .99, 52)}
    set{H5052, H1A - H2A}

    set{I52, count(Long_Profit > .99 , 52)}
    set{fivepct, count(Long_Profit > .05 , 52)}
    set{ziphi, count(whiop equal 0 , 52)}
    set{ziphix, count(whiop below 0.10 , 1)}
    set{onepct, count(Long_Profit > .01 , 52)}
    set{twopct, count(Long_Profit > .02 , 52)}
    set{halfpct, count(Long_Profit > .005 , 52)}
    set{qtrpct, count(Long_Profit > .0025 , 52)}

    add column wkProfitPct
    add column qtrpct
    add column halfpct
    add column onepct
    add column twopct
    add column fivepct

    add column ziphi


    and add column separator
    and add column C0010 {4_9}
    and add column D1020 {10_19}
    and add column E2030 {20_29}
    and add column F3040 {30_39}
    and add column G4050 {40_49}
    and add column H5052 {50_99}
    and add column I52 {100}
    and add column separator
    and add column weekly open {wopen}
    and add column weekly high {whigh}
    and add column weekly low {wlow}
    and add column weekly close {wclose}
    and add column separator

    close is above 1
    average volume(90) above 500000

    draw whiop
    draw ziphix
    sort column 9 descending

    date offset is 0

    /* Buy at close on Friday. Sell at 1% profit the next week */

    market not etf
    low > wma(150)

    set{Enter,close}
    set{1p,Enter * 1.01}
    set{5p,Enter * 1.05}
    set{Stoploss,Enter * .97}

    draw price line at 1p
    draw price line at 5p
    draw price line at Stoploss
    add column close
    set{Gaps,count(weekly open > weekly close 1 week ago,52)}
    add column Gaps
    ]



  • General Discussion · how to set a time dependency for 2 indicators
    xarlor
    msg #149611
    11/15/2019 2:46:37 PM

    This will get you close.

    Fetcher[
    /* Example CCI(14) below -100 within last 3 days and RSI(5) below 30 4 days ago */

    set{var1,count(CCI(14) < -100,3)}
    set{var2,count(RSI(5) 4 days ago < 30,1)}
    var1 > 0
    var2 > 0

    /* Aesthetics */

    draw CCI(14)
    draw RSI(5)

    draw CCI(14) line at -100
    draw RSI(5) line at 30
    ]



    General Discussion · functions and other mysterious keywords
    xarlor
    msg #149599
    11/14/2019 9:04:59 PM

    Things that were added after the Guide and Indicators can be found under "Announcements" from the main Forum page.

    Filter Exchange · ParaBEARic SAR into 52-week low
    xarlor
    msg #149594
    11/14/2019 12:17:10 PM

    Built this bearish swing-trade filter a while back and have had good success with it. Take profits early and don't be greedy with this one. You run a high risk of a bounce the longer you hold.

    Fetcher[

    /* Short or buy puts. Don't hold more than 30 days */

    optionable
    average volume(30) > 1234567
    chart-time is 1 year
    market not etf

    close < wma(150) for last 30 days
    Relative Strength(^SPX,150) < 1.0
    30-day slope of Relative Strength(^SPX,150) < 0

    parabolic sar 1 day ago < close 1 day ago
    parabolic sar > close

    close < low 52 week low 1 day ago
    close < open

    draw parabolic sar
    draw low 2-year low
    draw low 3-year low

    add column parabolic sar
    add column sector
    ]



    General Discussion · Newbie Needs Help With How to Code Screener
    xarlor
    msg #149583
    11/12/2019 8:03:46 PM

    Don't forget to share your filter if it turns out to be interesting!

    Fetcher[
    set{WkR,high 1 week high - low 1 week low}
    set{SMAx,ma(14) 1 week ago * 1.25}
    WkR > SMAx

    set{WkCL,close - low 1 week low}
    set{var1,WkCL / WkR}
    var1 < 0.25


    /* Debugging */

    add column high 1 week high
    add column low 1 week low
    add column WkR
    add column SMAx
    add column WkCL
    add column var1

    draw price line at high 1 week high
    draw price line at low 1 week low
    draw MA(14)
    ]



    StockFetcher Forums ·  · << 1 ... 3 4 5 6 7 ... 15 >>

    *** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


    Copyright 2018 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
    EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus