StockFetcher Forums · View by Author: xarlor (96 messages) ·  [ Display By: Date / Subject ]<< 1 ... 2 3 4 5 6 ... 10 >> 
General Discussion · Fibonacci screener
xarlor
msg #149299
modified
10/6/2019 9:26:39 PM

Not exactly what you asked for, but I made a filter that shows a bounce off a 52-week Fibonacci line.

Fetcher[
average volume(30) > 1234567
chart-time is 1 year
/* Set the Fib values at 23.6%, 38.2%, 50%, and 61.8%*/

set{Hi,high 1-year high}
set{Lo,low 1-year low}
set{Vdiff,Hi - Lo}
set{x1,Vdiff * .236}
set{x2,Vdiff * .382}
set{x3,Vdiff * .50}
set{x4,Vdiff * .618}
set{x5,Vdiff * .786}
set{Fib1, Hi - x1}
set{Fib2, Hi - x2}
set{Fib3, Hi - x3}
set{Fib4, Hi - x4}
set{Fib5, Hi - x5}

/* Check if price touched any of the Fib lines 1 day ago while that candle's body is above the Fib line */

set{touch1a,count(low 1 day ago <= Fib1,1)}
set{touch1b,count(close 1 day ago > fib1,1)}
set{touch1c,count(open 1 day ago > fib1,1)}
set{touch1d,touch1a * touch1b}
set{Touch1,touch1c * touch1d}

set{touch2a,count(low 1 day ago <= Fib2,1)}
set{touch2b,count(close 1 day ago > fib2,1)}
set{touch2c,count(open 1 day ago > fib2,1)}
set{touch2d,touch2a * touch2b}
set{Touch2,touch2c * touch2d}

set{touch3a,count(low 1 day ago <= Fib3,1)}
set{touch3b,count(close 1 day ago > fib3,1)}
set{touch3c,count(open 1 day ago > fib3,1)}
set{touch3d,touch3a * touch3b}
set{Touch3,touch3c * touch3d}

set{touch4a,count(low 1 day ago <= Fib4,1)}
set{touch4b,count(close 1 day ago > fib4,1)}
set{touch4c,count(open 1 day ago > fib4,1)}
set{touch4d,touch4a * touch4b}
set{Touch4,touch4c * touch4d}

set{touch5a,count(low 1 day ago <= Fib5,1)}
set{touch5b,count(close 1 day ago > fib5,1)}
set{touch5c,count(open 1 day ago > fib5,1)}
set{touch5d,touch5a * touch5b}
set{Touch5,touch5c * touch5d}

set{z1,Touch1 + Touch2}
set{z2,z1 + Touch3}
set{z3,z2 + Touch4}
set{Trigger,z3 + Touch5}
Trigger > 0

/* The bounce: Green day following a 3-day declining close */
close > high 1 day ago
close 1 day ago < close 2 days ago for last 3 days

draw price line at hi
draw price line at Fib1
draw price line at Fib2
draw price line at Fib3
draw price line at Fib4
draw price line at Fib5
draw price line at lo

do not draw Trigger

/* Debugging

add column hi
add column Vdiff
add column fib1
add column close 1 day ago
*/
]



Stock Picks and Trading · A Newbie's Journey
xarlor
msg #149290
10/5/2019 6:03:57 PM

Added two lines at the bottom to tighten up the number of results.

Fetcher[
market is etf
set{1A_1, count (close > bottom linear regression line(13,0.75) 1 day ago,1)}
set{1A_2, count (LRS(13) < 0,1)}
set{1A, 1A_1 * 1A_2}

set{2A, count(rsi(14) crossed above 40,1)}

set{trigger, 1A * 2A}
add column trigger > 0

add column 1A
add column 2A
add column rsi(14)

average volume(30) > 123456
low > wma(150)
]



Public Filter List · Draw Gann Square of Nine (SQ9) Levels on Charts
xarlor
msg #149289
10/5/2019 5:44:50 PM

Impressive filter, manifestation. I do want to point out that SF does not recognize highs and lows beyond 3 years: So the line below is substituting your 5-year high iwth the 3-year high.

set{MajorPoint, High 5 year high * DigitMultiplier} // The reference top/bottom. You may change it to a specific number

Fetcher[
optionable
add column high 10-year high
add column high 9-year high
add column high 8-year high
add column high 7-year high
add column high 6-year high
add column high 5-year high
add column high 4-year high
add column high 3-year high
add column high 2-year high
add column high 1-year high

high 1-year high < high 2-year high
high 2-year high < high 3-year high
]



Stock Picks and Trading · A Newbie's Journey
xarlor
msg #149287
10/5/2019 4:35:22 PM

sandjco, there's probably better ways to find breaking trendlines, but this is what I use in my filters.

Unfortunately, when looking back, the LRC always draws with today's data, instead of however long you're looking back. The filter is still showing correctly, it's just the LRC lines display based on today's data. Go back a month to see what I mean.

Still, it does a reasonable job of showing a breakout of a trend.


Fetcher[
/* Breaking downward trend */
optionable
close > top linear regression line(38,0.75) 1 day ago
LRS(38) < 0
]



Filter Exchange · Creating a specific Filter
xarlor
msg #149270
10/2/2019 6:44:14 PM

There's even a specific indicator for that one:

https://www.stockfetcher.com/forums/Indicators/Close-to-open-Gap/25005

Fetcher[
close > 10
close-to-open gap > .05
add column close-to-open gap
]



Filter Exchange · Probably The Best ETF Filter
xarlor
msg #149235
9/25/2019 7:34:46 PM

With BUY markers for look-back purposes:

Fetcher[
set{var1,count(weekly indposition(obv,50) is below .20,1)}
set{var2,count(weekly mfi (10) is below 20,1)}
set{var3,count(weekly rsi(14) is below 35,1)}
/* set{var0,count(fisher transform(10) is below,1)} */
set{var4,var1 * var2}
set{BUY,var4 * var3}
BUY > 0

Draw weekly Williams %r(14) line at -80
Draw Weekly Williams %r(14) line at -22 etf
add column stderr(close,45)
draw weekly indposition(obv,50) line at .20
draw weekly indposition(obv,50) line at .80
DRAW WEEKLY MFI(10) line AT 80
DRAW WEEKLY MFI(10) line AT 20
draw weekly rsi(14) line at 35
draw weekly rsi(14) line at 70
draw weekly rsi(14) line at 63
draw weekly rsi(14) line at 30
draw weekly aroon(25) up
draw weekly aroon(25) down
draw weekly aroon(25) down line at 99
draw weekly aroon(25) down line at 1
draw fisher transform(10)
draw fisher transform(10) line at 4
draw fisher transform(10) line at -4
draw linear regression slope(10)
draw linear regression slope(10) line at 1
]



Filter Exchange · Modified OBV request/help!
xarlor
msg #149229
9/24/2019 6:41:52 PM

Maybe?

Fetcher[
close > 10
set{var1,close - close 1 day ago}
set{var2,volume * var1}
set{var3,var2 1 day ago}
set{OBVx,var2 + var3}

draw OBVx
draw OBV
draw OBVx line at 0
draw OBV line at 0
]



General Discussion · faulty ROC filter returns?
xarlor
msg #149224
9/24/2019 11:18:22 AM

SPI had a reverse stock split on 11/16/18. StockFetcher's prices do not retroactively adjust for splits, so about a year ago, SPI was trading for around 0.30.

Fetcher[
symlist(SPI)
chart-time is 1 year
add column close 250 days ago
]



Filter Exchange · Newbie needs help :)
xarlor
msg #149202
9/21/2019 1:59:39 PM

Fetcher[
chart-display is weekly
chart-time is 1 year

Show stocks were EMA(20) is above EMA(40)
and EMA(40) is above MA(50)
and MA(50) is above MA(100) for the last 20 weeks
and MA(100) is above MA(150) for the last 20 weeks
and MA(150) is above MA(200) for the last 20 weeks
and close 1 week ago is above close 2 weeks ago
and Stochastic %K(15,5,3) < 20
Stochastic %D(15,5,3) < 20

and volume is above 200000

draw MACD Histogram(12,26,9)
]



Filter Exchange · Bulkowski's Reversal
xarlor
msg #149201
9/21/2019 11:31:56 AM

Been messing around with Bulkowski's Weekly Reversal pattern and adapting it to daily for swing trading.

Fetcher[
/* Bulkowski's Reversal */

optionable
average volume(30) > 1234567

/* Price action away from wma(150) to exclude false positives */
set{a1,count(price touched wma(150),10)}
a1 < 1
do not draw a1

/* Reversal signal */
set{var1,count(high 1 day ago > high 2 days ago,1)}
set{var2,count(close 1 day ago < low 2 days ago,1)}
set{var3,count(open 1 day ago > open 2 days ago,1)}
set{var4,var1 * var2}
set{signal,var3 * var4}

/* Long confirmation */
set{x1,count(close > high 1 day ago,1)}
set{x2,count(low > wma(150),1)}
set{x3,x1 * x2}
set{LONG,x3 * signal}

/* Short confirmation */
set{z1,count(close < low 1 day ago,1)}
set{z2,count(high < wma(150),1)}
set{z3,z1 * z2}
set{SHORT,z3 * signal}

set{trigger,LONG + SHORT}
trigger > 0

draw LONG
draw SHORT
do not draw trigger
]



StockFetcher Forums ·  · << 1 ... 2 3 4 5 6 ... 10 >>

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2018 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus