StockFetcher Forums · View by Author: (111 messages)  [ Display By: Date / Subject ]<< 1 2 3 4 5 ... 12 >> 
General Discussion · "once over past 30 days?"
olathegolf
msg #152994
7/6/2020 11:48:57 PM

Fetcher[
volume(30) above 200000
price above 0.5
/*open to close gain*/
set{gain,close/open}
set{10%gain,count(gain above 1.1,30)}
10%gain above 0
add column 10%gain
sort column 5 descending
]



Filter Exchange · Need help scanning for prior 4 week range
olathegolf
msg #152424
6/3/2020 11:38:17 AM

Added High 4-week High Filter
Plotted 4 week highs and lows - 1 day ago for clarity on charts

Fetcher[
Average volume(30) above 200000
Price above 1

/*Low 4 Week Low Filter*/
set{4wklo_1dago,low 4 week low 1 day ago}
set{x,count(low crossed below 4wklo_1dago,1)}
set{y,count(close below 4wklo_1dago,1)}
set{z,x+y}
draw 4wklo_1dago on plot price
add column separator
add column 4wkl_1dago {4 week low}
add column x {cross below 4 week low}
add column y {close below 4 week low}
add column z {cross and close below 4 week low}
add column separator

/*High 4 Week High Filter*/
set{4wkhi_1dago,high 4 week high 1 day ago}
set{p,count(high crossed above 4wkhi_1dago,1)}
set{d,count(close above 4wkhi_1dago,1)}
set{q,p+d}
draw 4wkhi_1dago on plot price
add column 4wkhi_1dago {4 week high}
add column p {cross above 4 week high}
add column d {close above 4 week high}
add column q {cross and close above 4 week high}
set{tot,z+q}
tot above 0
sort column 8 descending
]



Filter Exchange · Need help scanning for prior 4 week range
olathegolf
msg #152423
6/2/2020 11:31:08 PM

Maybe something like this....
Fetcher[
/*From Rock Sexton: Looking for a filter that identifies when the current price pierces or closes below the low of the prior 4 week range. Thanks ahead of time for anyone willing to share.*/

Average volume(30) above 200000
Price above 1
set{a,low 4 week low 1 day ago}
set{x,count(low crossed below a,1)}
set{y,count(close below a,1)}
set{z,x+y}
z above 0
draw low 4 week low on plot price
add column a {4 week low}
add column x {cross below 4 week low}
add column y {close below 4 week low}
add column z {cross and close below 4 week low}
]



General Discussion · How to filter stocks that are about to do a bullish MACD crossover
olathegolf
msg #151845
4/16/2020 10:23:57 PM

The purpose of the last filter was to see how these stocks generally performed 5 days after the signal was triggered. For the calculation, it assumes:

1. You jump in early before crossover and buy at the open the day following the signal. I'm not necessarily advocating that.
2. P/L is calculated based on the 5 day high following the signal.

I simply wanted to see if stocks popped in the days following the signal. It's really not much more than that. The first two filters address your initial question.

Most stocks follow the general market direction. You can easily see that here. Run the 3rd filter and back up to a point that correlates to the trigger date in early April - a time when the market began an upward trend. You'll see that many of the stocks selected also popped with potential double digit gains over the 5 day period.

General Discussion · How to filter stocks that are about to do a bullish MACD crossover
olathegolf
msg #151833
4/15/2020 1:32:17 AM

This is a simple 5 day test.
Crossover has not happened, but it assumes entry at the open the day following the signal.
You can walk backwards in time and see what the max profit would be the following 5 days.

Fetcher[
/* MACD Close to a Bullish Cross - 5d Test*/
Close 5 days ago above 2
Average volume(30) 5 days ago above 250000
Chart-time is 6 months

2 day Slope of MACD(12,26,9) Fast Line 5 days ago above 0
MACD Histogram(12,26,9) 5 days ago below 0

Add column MACD Histogram(12,26,9) 5 days ago
Add column 2 day slope of MACD(12,26,9) Fast Line 5 days ago
Sort column 5 descending /*Could Also Sort column 10 Ascending Based on Lowest Weighting...or Suggest a Better Correlation*/

/*5 Day Max Profit Check - Assume Entry Next Day at Open (Prior to Crossover Confirmation)*/
set{Profit1,high 4 day high/open 4 days ago}
set{Profit2,Profit1-1}
set{Profit,Profit2*100}
Add column Profit {Potential Profit%}

/*Proximity to 5d, 21d, 63d Close Lows*/
set{5dl,close 5 day low 5 days ago}
set{21dl,close 21 day low 5 days ago}
set{63dl,close 63 day low 5 days ago}
set{c5,close 5 days ago}
set{5dlprox1,c5 - 5dl}
set{5dlprox2,5dlprox1/5dl}
set{5dlprox,abs(5dlprox2)}
set{21dlprox1,c5 - 21dl}
set{21dlprox2,21dlprox1/21dl}
set{21dlprox,abs(21dlprox2)}
set{63dlprox1,c5 - 63dl}
set{63dlprox2,63dlprox1/63dl}
set{63dlprox,abs(63dlprox2)}
set{weight1,3*63dlprox}
set{weight2,2*21dlprox}
set{weight3,5dlprox}
set{weight4,weight1+weight2}
set{weight,weight3+weight4} /*WAG at Weighting Close Proximity to 5d, 21d and 63d lows*/

draw price line at 5dl
draw price line at 21dl
draw price line at 63dl
add column 5dlprox
add column 21dlprox
add column 63dlprox
add column weight
]



General Discussion · How to filter stocks that are about to do a bullish MACD crossover
olathegolf
msg #151832
4/15/2020 1:19:35 AM

Added Approx. weekly, monthly and quarterly lows:
Fetcher[
/* MACD Close to a Bullish Cross*/
Close above 2
Average volume(30) above 250000
Chart-time is 6 months

2 day Slope of MACD(12,26,9) Fast Line above 0
MACD Histogram(12,26,9) below 0

Add column MACD Histogram(12,26,9)
Add column 2 day slope of MACD(12,26,9) Fast Line
Sort column 5 descending /*Could Also Sort column 10 Ascending Based on Lowest Weighting*/

/*Proximity to 5d, 21d, 63d Low Close*/
/*Move Could Have More Conviction if Bouncing off Support*/
set{5dl,close 5 day low}
set{21dl,close 21 day low}
set{63dl,close 63 day low}
set{5dlprox1,close - 5dl}
set{5dlprox2,5dlprox1/5dl}
set{5dlprox,abs(5dlprox2)}
set{21dlprox1,close - 21dl}
set{21dlprox2,21dlprox1/21dl}
set{21dlprox,abs(21dlprox2)}
set{63dlprox1,close - 63dl}
set{63dlprox2,63dlprox1/63dl}
set{63dlprox,abs(63dlprox2)}
set{weight1,3*63dlprox}
set{weight2,2*21dlprox}
set{weight3,5dlprox}
set{weight4,weight1+weight2}
set{weight,weight3+weight4} /*WAG at Weighting Close Proximity to 5d, 21d and 63d lows*/

draw price line at 5dl
draw price line at 21dl
draw price line at 63dl
add column 5dlprox
add column 21dlprox
add column 63dlprox
add column weight
]



General Discussion · How to filter stocks that are about to do a bullish MACD crossover
olathegolf
msg #151831
4/14/2020 11:54:55 PM

How about something like this:
Fetcher[
/* MACD Close to a Bullish Cross */
Close above 2
Average volume(30) above 250000

Slope of MACD(12,26,9) Fast Line above 0
MACD Histogram(12,26,9) below 0

Add column MACD Histogram(12,26,9)
Add column slope of MACD(12,26,9) Fast Line
Sort column 5 descending
]



General Discussion · What is wrong with this filter?
olathegolf
msg #151498
3/27/2020 1:18:05 PM

Maybe something like this:
Fetcher[
set{10dhi,count(high above 3 month high 25 days ago,10)}
10dhi above 0
add column 3 month high 25 days ago
add column 10dhi
]



Stock Picks and Trading · Village Elder Short -Sell Filter discussions
olathegolf
msg #151227
3/14/2020 9:25:42 PM

As you screen stocks using VEs filter, you might find it useful to know if a stock split occurred recently. Use the following website: https://www.stocksplithistory.com/

Also, does anybody know the easiest way to screen for acquisitions? Luckily, there aren't many stocks selected so it's easy enough to just search on the internet. However, if you know of a dedicated screener, please advise. Thanks.

Stock Picks and Trading · Village Elder Short -Sell Filter discussions
olathegolf
msg #151050
3/3/2020 12:33:09 AM

VE - thanks again for your contributions.

Nibor - 3 day lookback was necessary to calculate 1 day, 2 day, and 3 day profits. As I mentioned, I manually downloaded the CSV file for each days results, pasted into an Excel spreadsheet and performed a simple analysis from there - mostly related to VEs various exit strategies.

Other than the obvious outlier OVV, I did not remove any selections.

Here's VEs filter modified using a 3 day lookback with 3 day results:

Fetcher[
/*Village Elder Short-Sell Filter with 3 Day Lookback*/

close 3 days ago above 3
close 3 days ago above close 4 days ago
close 3 days ago * volume 3 days ago above 1000000
set{mass5, average volume(5) 3 days ago / average volume(50) 3 days ago}
set{new_momentum, ROC(5,1) 3 days ago * mass5}
draw roc(5,1) 3 days ago line at 50
add column new_momentum
add column roc(5,1) 3 days ago{roc51}
sort on column 5 descending
roc(5,1) 3 days ago above 50
Market cap 3 days ago above 10 /*Nibor is Using Shares Outstanding 3 days ago above 10"*/
add column market cap 3 days ago
chart-time is 3 months

/*Calculate Profit*/

/*After Day 1*/
set{profit1h,open 2 days ago - high 2 days ago}
set{profit1min,profit1h/open 2 days ago}
set{profit1a, open 2 days ago - close 2 days ago}
set{profit1d_close,profit1a/open 2 days ago}
set{profit1e,open 2 days ago - low 2 days ago}
set{profit1max,profit1e/open 2 days ago}

/*After Day 2*/
set{profit2h,open 2 days ago - high 1 day ago}
set{profit2min,profit2h/open 2 days ago}
set{profit2a, open 2 days ago - close 1 day ago}
set{profit2d_close, profit2a/open 2 days ago}
set{profit2e,open 2 days ago - low 1 day ago}
set{profit2max,profit2e/open 2 days ago}

/*After Day 3*/
set{profit3h,open 2 days ago - high}
set{profit3min,profit3h/open 2 days ago}
set{profit3a, open 2 days ago - close}
set{profit3d_close, profit3a/open 2 days ago}
set{profit3e,open 2 days ago - low}
set{profit3max,profit3e/open 2 days ago}

/*Viewing*/

add column separator
add column open 2 days ago {Sell Short Price}
add column separator
add column profit1min
add column profit1d_close
add column profit1max
add column separator
add column profit2min
add column profit2d_close
add column profit2max
add column separator
add column profit3min
add column profit3d_close
add column profit3max
add column separator
add column ROC(5,1) 2 days ago {ROC51 d1}
add column ROC(5,1) 1 day ago {ROC51 d2}
add column ROC(5,1) {ROC51 d3}
add column separator
]



StockFetcher Forums ·  · << 1 2 3 4 5 ... 12 >>

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2018 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus