StockFetcher Forums · Filter Exchange · Another Weinstein filter<< 1 2 >>Post Follow-up
graftonian
815 posts
msg #148267
Ignore graftonian
6/24/2019 6:22:52 PM

This filter seems to work pretty well, if one catches the WMA cross early, looks for the volume spike, and don't forget the Mansfield Relative strength, The gold ETFs are going ape-shit right now, and this filter picked them up early.

Fetcher[
optionable
Average Volume(252) > 5000000
chart-time is 6 months

DRAW WMA(150)
DRAW WMA(5)
add column separator
/*WMA(150) CROSS?
NOT USED */
set{WMAcross1, count(WMA(5) CROSSED aBOVE WMA(150), 1)}
set{WMAcross2, count(WMA(5) CROSSED BELOW WMA(150), 1)}
set{WMAcross, WMAcross1 - WMAcross2}


/*PRICE ABOVE WMA(150)?*/
set{PRICEabv1, count(close > WMA(150), 1)}
set{PRICEabv2, count(close < WMA(150), 1)}
set{PRICEabv, PRICEabv1 - PRICEabv2}
add column PRICEabv

/*slope of WMA(150) > 0? */
set{WMAslope1, count(slope of WMA(150) > 0.01, 1)}
set{WMAslope2, count(slope of WMA(150) < -0.01, 1)}
set{WMAslope, WMAslope1 - WMAslope2}
add column WMAslope
/*MANSFIELD RELATIVE PERFORMANCE*/
set{RSD1, close / ind(SPY, close)}
set{RSD, RSD1 * 100}
/*RSM = (( RSD(today) / sma(RSD(today), n)) - 1 ) * 100 */
Set{X1, cma(RSD, 253)}
set{X2, RSD / X1}
set{X3, X2 - 1}
set{RSM, X3 * 100}
DRAW RSD
DRAW RSM ON PLOT RSD

/*RSM abv RSD? */
set{RSMabvRSD1, count(RSM > RSD, 1)}
set{RSMabvRSD2, count(RSM < RSD, 1)}
set{RSMabvRSD, RSMabvRSD1 - RSMabvRSD2}
add column RSMabvRSD
/*sum the components*/
set{sum1, WMAcross + PRICEabv}
set{sum2, sum1 + WMAslope}
set{sum3, sum2 + RSMabvRSD}
set{STAGEII, CWMA(sum3, 3)}

set{Y1, days(STAGEII < 2, 252)}
y1 > 0
add column y1{DAYS_INTO_2}
do not draw y1
sort on column 9 ascending

add column STAGEII sort on column 9 descending
plottype{STAGEII, zerobar}
draw STAGEII
draw STAGEII line at 0
add column separator
add column slope of WMA(150)
/*FILTER*/
STAGEII > 2.1
vol_pct > 0
/*volume pct */
set{vp1, CWMA(VOLUME, 3) - Average Volume(252)}
set{vp2, vp1 / Average Volume(252)}
set{vol_pct, vp2 * 100}
add column vol_pct
draw vol_pct
draw vol_pct line at 100
]












davesaint86
503 posts
msg #148273
Ignore davesaint86
6/25/2019 8:38:38 AM

https://the7circles.uk/stan-weinsteins-stage-system-1-charts-buying/


davesaint86
503 posts
msg #148274
Ignore davesaint86
6/25/2019 8:40:23 AM

https://www.nextbigtrade.com/stage-analysis/

davesaint86
503 posts
msg #148275
Ignore davesaint86
6/25/2019 8:54:51 AM

http://thepatternsite.com/Stages.html


graftonian
815 posts
msg #148276
Ignore graftonian
6/25/2019 10:47:47 AM

Davesaint, Thanks for the links. Now to write a filter to define Stage1
Graf

graftonian
815 posts
msg #148621
Ignore graftonian
7/21/2019 6:47:55 PM

The latest version of my Weinstein filter
Fetcher[
/*WEINSTEIN WATCHLIST*/
chart-time is 1 year
symlist(mu)
draw WMA(150)
draw average volume(150)
draw cwma(volume, 3)

set{RSD1, close / ind(spy, close)}
set{RSD, RSD1 * 100} /*this is DorseyRS*/
set{RSD252MA, cma(RSD, 252)}
set{RSM1, RSD / RSD252MA}
set{RSM2, RSM1 -1}
set{RSM, RSM2 * 100}
draw RSM
draw RSM line at 0
add column RSM{Mansfield}

set{vol_x, volume / average volume(50)}
add column vol_x

add column sector
add column separator
/*condition 1 - close above WMA(150) */
set{cond1, count(close > WMA(150), 1)}
add column cond1{1}
/*condition 2 - slope of WMA(150) > 0 */
set{cond2, count(2 day slope of WMA(150) > 0, 1)}
add column cond2{2}
/*condition 3 - Mansfield RS > 0 */
set{cond3, count(RSM > 0, 1)}
add column cond3{3}
/*condition 4 - SLope of Mansfield RS > 0 */
set{cond4, count(2 day slope of RSM > 0, 1)}
add column cond4{4}
/*condition 5 - volume multiple above avg volume */
set{cond5, count(Vol_X > 1.5, 1)}
add column cond5{5}
/* sum the above conditions */
set{sn1, cond1 + cond2}
set{sn2, sn1 + cond3}
set{sn3, sn2 + cond4}
set{sn4, sn3 + cond5}
set{sort_num, sn4 + Vol_X}
add column sort_num

sort on column 14 descending
/*schaff trend cycle */
set{var1, ema(23) - ema(50)}
set{highest, var1 10 day high}
set{lowest, var1 10 day low}
set{range, highest - lowest}
set{var2, var1 - lowest}
set{var3, var2 / range}
set{var4, cema(var3, 3)}
set{var6, var4 10 day high}
set{var5, var4 10 day low}
set{var7, var4 - var5}
set{var8, var6 - var5}
set{var9, var7 / var8}
set{var10, cema(var9, 3)}
set{stclong, 100 * var10}

add column STClong
draw stclong




]



roca1018
108 posts
msg #148656
Ignore roca1018
7/23/2019 5:45:41 AM

Graf,

Can you write one within the limits of the basic subscription?

Thanks

Rich

graftonian
815 posts
msg #148662
Ignore graftonian
7/23/2019 10:09:29 AM

Rich, I am only a basic subscriber, this should work for all. The section dealing with STC has been a bity troublesome; try removing it and replacing with the new code posted by Nibor.
Graf

pa247
143 posts
msg #148667
Ignore pa247
7/23/2019 3:30:12 PM

I get this when I try to run this filter or the one Nibor did on another thread.

"This StockFetcher filter exceeds filter performance restrictions.

To run this filter, please upgrade to the StockFetcher Advanced subscription level.. "

graftonian
815 posts
msg #148669
Ignore graftonian
7/24/2019 9:10:26 AM

I am at a loss for an answer. my last SF fee was$8.95. Go figure.

StockFetcher Forums · Filter Exchange · Another Weinstein filter<< 1 2 >>Post Follow-up

*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2018 - Vestyl Software L.L.C.Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus